Файл:Euclidian_and_non_euclidian_geometry.png
З Вікіпедії, безкоштовно encyclopedia
![Файл:Euclidian and non euclidian geometry.png](http://upload.wikimedia.org/wikipedia/commons/thumb/5/5e/Euclidian_and_non_euclidian_geometry.png/800px-Euclidian_and_non_euclidian_geometry.png)
Повна роздільність (4000 × 1500 пікселів, розмір файлу: 128 КБ, MIME-тип: image/png)
![]() |
Відомості про цей файл містяться на Вікісховищі — централізованому сховищі вільних файлів мультимедіа для використання у проектах Фонду Вікімедіа. |
Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate
- euclidian
- elliptical and
- hyperbolic geometry
To be exact, the hyperbolic surface was approximated using a chunk of the "inside" of a torus - this may not be perfectly accurate, but apparently it "looks right" in this illustration. :-)
Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped and "numbered" using a graphics software package.
Povray source code |
---|
/*
====================================================================
Surfaces demonstrating euclidian, elliptical and hyperbolic geometry
--------------------------------------------------------------------
Created by Søren Peo Pedersen - see my user page at
http://da.wikipedia.org/wiki/Bruger:Peo
====================================================================
*/
// Macro for texture with background pattern, lines, and point "marker"
#macro SurfaceDrawing (
Point, // Position vector: Location of white point
RefLineMove, // Transformation: Where to place the yellow reference line
Lines // Object that renders the blue line(s)
)
#local BasePattern=pigment { // The underlying, dark grey checkerboard pattern
checker
color rgb 0.4
color rgb 0.6
scale <1,1000,1>
}
#local SP1 = pigment { // Checkerboard pattern with yellow "reference line" added
object {box {<-.07,-10,-10>,<.07,10,10> transform{RefLineMove}}
pigment {BasePattern}
pigment {color rgb <1,.8,.3>}
}
}
#local SP2 = pigment { // Checkerborad + yellow line with user-defined (blue) lines added
object {Lines
pigment {SP1}
pigment {color rgb <.6,.8,1>}
}
}
#local SP3 = pigment { // Checkerboard + lines with whit point "marker" added
object {
sphere { Point, .2 }
pigment {SP2}
pigment {color rgb 1}
}
}
pigment { // Definition of pigment, confined to a box slightly smaller than the "blocks"
boxed // to make the lines and point only appear on the top of the blocks
pigment_map {
[0.0000 BasePattern scale .5 translate <0,-1,0>]
[0.0001 BasePattern scale .5 translate <0,-1,0>]
[0.0001 SP3 scale .5 translate <0,-1,0>]
[1.0000 SP3 scale .5 translate <0,-1,0>]
}
scale <2,2,2> translate <0,2,0>
}
finish {ambient .7 diffuse .3}
#end // End of macro
plane {<0,1,0>,0 // White "tabletop" to receive shadows of the blocks (helps visualisation)
pigment {color rgb 1}
finish {ambient .8 diffuse .5}
}
box {<-2,0,-2>,<2,2,2> // Demonstrating euclidean geometry
texture {
SurfaceDrawing(<-.3,2,0>,
transform {rotate <0,35,0> translate <.3,0,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,35,0> translate <-.3,0,0>}
)
}
rotate <0,-20,0>
translate <-6,0,0>
}
intersection { // Demonstrating elliptical, or "Riemann", geometry
box {<-2,0,-2>,<2,5,2>}
sphere {<0,0,0>,2.8285}
texture {
SurfaceDrawing(<.65,2.45,1.25>,
transform {rotate <0,5,0> rotate <-45,35,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,-4,0> rotate <-45,35,0>}
)
}
rotate <0,-20,0>
translate <0,0,0>
}
intersection { // Demonstrating hyperbolic geometry
box {<-2,0,-2>,<2,4,2>}
torus {7.03,5 rotate <90,90,0> translate <0,4,0>}
texture {
SurfaceDrawing(<0,2.3,1>,
transform {rotate <0,90,0> rotate <-40,0,0> translate <0,4,0>},
merge {
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,85,0> rotate <-30,0,0> translate <0,4,0>
}
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,95,0> rotate <-30,0,0> translate <0,4,0>
}
}
)
}
rotate <0,-20,0>
translate <6,0,0>
}
camera { // Viewpoint
location <0,2100,-800>
look_at <.5,0,0>
angle .47
}
light_source {<-50,200,-100> color rgb 1.5} // Illumination
|
![]() |
Дозволяється копіювати, розповсюджувати та/або модифікувати цей документ на умовах ліцензії GNU FDL версії 1.2 або більш пізньої, виданої Фондом вільного програмного забезпечення, без незмінних розділів, без текстів, які розміщені на першій та останній обкладинці. Копія ліцензії знаходиться у розділі GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
![]() ![]() ![]() |
Цей файл ліцензований на умовах ліцензії Creative Commons Attribution-Share Alike 3.0 Unported | |
| ||
Цей шаблон ліцензування був доданий до файлу в рамках оновлення ліцензії GFDL.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue |
Підписи
Об'єкти, показані на цьому файлі
зображує
image/png
Історія файлу
Клацніть на дату/час, щоб переглянути, як тоді виглядав файл.
Дата/час | Мініатюра | Розмір об'єкта | Користувач | Коментар | |
---|---|---|---|---|---|
поточний | 21:47, 5 липня 2015 | ![]() | 4000 × 1500 (128 КБ) | Cmdrjameson | Compressed with pngout. Reduced by 66kB (34% decrease). |
19:13, 4 серпня 2012 | ![]() | 4000 × 1500 (194 КБ) | Morn | redone at higher resolution | |
23:21, 7 квітня 2005 | ![]() | 790 × 310 (47 КБ) | Peo~commonswiki | Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate #euclidian #elliptical and #hyperbolic geometry Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped an |
Використання файлу
Така сторінка використовує цей файл:
Глобальне використання файлу
Цей файл використовують такі інші вікі:
- Використання в ar.wikipedia.org
- Використання в arz.wikipedia.org
- Використання в ast.wikipedia.org
- Використання в az.wikipedia.org
- Використання в ba.wikipedia.org
- Використання в bg.wikipedia.org
- Використання в cs.wikipedia.org
- Використання в en.wikipedia.org
- Використання в eo.wikipedia.org
- Використання в et.wikipedia.org
- Використання в fa.wikipedia.org
- Використання в fr.wikipedia.org
- Використання в gl.wikipedia.org
- Використання в he.wikipedia.org
- Використання в hy.wikipedia.org
- Використання в id.wikipedia.org
- Використання в ja.wikipedia.org
- Використання в ka.wikipedia.org
- Використання в kk.wikipedia.org
- Використання в la.wikipedia.org
- Використання в nl.wikipedia.org
- Використання в nn.wikipedia.org
- Використання в no.wikipedia.org
- Використання в pl.wikipedia.org
- Використання в tg.wikipedia.org
- Використання в tt.wikipedia.org
- Використання в uk.wikiquote.org
- Використання в uz.wikipedia.org
- Використання в vi.wikipedia.org
- Використання в www.wikidata.org
Метадані
Файл містить додаткові дані, які зазвичай додаються цифровими камерами чи сканерами. Якщо файл редагувався після створення, то деякі параметри можуть не відповідати цьому зображенню.
Горизонтальна роздільна здатність | 35,43 точок на сантиметр |
---|---|
Вертикальна роздільна здатність | 35,43 точок на сантиметр |
Дата й час редагування файлу | 19:09, 4 серпня 2012 |