Loading AI tools
Microsoft programming language From Wikipedia, the free encyclopedia
F# (pronounced F sharp) is a general-purpose, high-level, strongly typed, multi-paradigm programming language that encompasses functional, imperative, and object-oriented programming methods. It is most often used as a cross-platform Common Language Infrastructure (CLI) language on .NET, but can also generate JavaScript[7] and graphics processing unit (GPU) code.[8]
![]() | |
Paradigms | Multi-paradigm: functional, imperative, object-oriented, agent-oriented, metaprogramming, reflective, concurrent |
---|---|
Family | ML: Caml: OCaml |
Designed by | Don Syme, Microsoft Research |
Developer | Microsoft, The F# Software Foundation |
First appeared | 2005 | , version 1.0
Stable release | 8.0.0
/ 14 November 2023 |
Typing discipline | Static, strong, inferred |
OS | Cross-platform: .NET framework, Mono |
License | MIT[1][2] |
Filename extensions | .fs, .fsi, .fsx, .fsscript |
Website | fsharp
|
Influenced by | |
C#, Erlang, Haskell,[3] ML, OCaml,[4][5] Python, Scala | |
Influenced | |
C#,[6] Elm, F*, LiveScript | |
|
F# is developed by the F# Software Foundation,[9] Microsoft and open contributors. An open source, cross-platform compiler for F# is available from the F# Software Foundation.[10] F# is a fully supported language in Visual Studio[11] and JetBrains Rider.[12] Plug-ins supporting F# exist for many widely used editors including Visual Studio Code, Vim, and Emacs.
F# is a member of the ML language family and originated as a .NET Framework implementation of a core of the programming language OCaml.[4][5] It has also been influenced by C#, Python, Haskell,[3] Scala and Erlang.
F# version |
Language specification | Date | Platforms | Runtime |
---|---|---|---|---|
1.x | May 2005[13] | Windows | .NET 1.0 - 3.5 | |
2.0 | August 2010 | April 2010[14] | Linux, macOS, Windows | .NET 2.0 - 4.0, Mono |
3.0 | November 2012 | August 2012[15] | Linux, macOS, Windows; JavaScript,[7] GPU[8] |
.NET 2.0 - 4.5, Mono |
3.1 | November 2013 | October 2013[16] | Linux, macOS, Windows; JavaScript,[7] GPU[8] |
.NET 2.0 - 4.5, Mono |
4.0 | January 2016 | July 2015[17] | ||
4.1 | May 2018 | March 2017[18] | Linux, macOS, Windows, | .NET 3.5 - 4.6.2, .NET, Mono |
4.5 | August 2018[19] | Linux, macOS, Windows, | .NET 4.5 - 4.7.2,[20] .NET Core SDK 2.1.400[21] | |
4.6 | March 2019[22] | Linux, macOS, Windows, | .NET 4.5 - 4.7.2,[23] .NET Core SDK 2.2.300[24] | |
4.7 | September 2019[25] | Linux, macOS, Windows, | .NET 4.5 - 4.8,[26] .NET Core SDK 3.0.100[27] | |
5.0 | November 2020[28] | Linux, macOS, Windows, | .NET SDK 5.0.100[29] | |
6.0 | November 2021[30] | Linux, macOS, Windows, | .NET SDK 6.0.100[31] | |
7.0 | November 2022[32] | Linux, macOS, Windows, | .NET SDK 7.0.100[33] | |
8.0 | November 2023[34] | Linux, macOS, Windows, | .NET SDK 8.0.100[35] |
F# uses an open development and engineering process. The language evolution process is managed by Don Syme from Microsoft Research as the benevolent dictator for life (BDFL) for the language design, together with the F# Software Foundation. Earlier versions of the F# language were designed by Microsoft and Microsoft Research using a closed development process.
F# was first included in Visual Studio in the 2010 edition, at the same level as Visual Basic (.NET) and C# (albeit as an option), and remains in all later editions, thus making the language widely available and well-supported.
F# originates from Microsoft Research, Cambridge, UK. The language was originally designed and implemented by Don Syme,[4] according to whom in the fsharp team, they say the F is for "Fun".[36] Andrew Kennedy contributed to the design of units of measure.[4] The Visual F# Tools for Visual Studio are developed by Microsoft.[4] The F# Software Foundation developed the F# open-source compiler and tools, incorporating the open-source compiler implementation provided by the Microsoft Visual F# Tools team.[9]
F# version |
Features added | |
---|---|---|
1.0 |
| |
2.0 |
| |
3.0[37] |
| |
3.1[38] |
| |
4.0[39] |
| |
4.1[40] |
| |
4.5[28] |
| |
4.6 |
| |
4.7[41] |
| |
5.0[42] |
| |
6.0[43] |
| |
7.0[44] |
| |
8.0[45] |
| ] collection expressions
|
F# is a strongly typed functional-first language with a large number of capabilities that are normally found only in functional programming languages, while supporting object-oriented features available in C#. Together, these features allow F# programs to be written in a completely functional style and also allow functional and object-oriented styles to be mixed.
Examples of functional features are:
F# is an expression-based language using eager evaluation and also in some instances lazy evaluation. Every statement in F#,
including if
expressions, try
expressions and loops, is a composable expression with a static type.[49] Functions and expressions that do not return any value have a return type of unit
. F# uses the let
keyword for binding values to a name.[49] For example:
let x = 3 + 4
binds the value 7
to the name x
.
New types are defined using the type
keyword. For functional programming, F# provides tuple, record, discriminated union, list, option, and result types.[49] A tuple represents a set of n values, where n ≥ 0. The value n is called the arity of the tuple. A 3-tuple would be represented as (A, B, C)
, where A, B, and C are values of possibly different types. A tuple can be used to store values only when the number of values is known at design-time and stays constant during execution.
A record is a type where the data members are named. Here is an example of record definition:
type R =
{ Name : string
Age : int }
Records can be created as let r = { Name="AB"; Age=42
}. The with
keyword is used to create a copy of a record, as in { r with Name="CD"
}, which creates a new record by copying r
and changing the value of the Name
field (assuming the record created in the last example was named r
).
A discriminated union type is a type-safe version of C unions. For example,
type A =
| UnionCaseX of string
| UnionCaseY of int
Values of the union type can correspond to either union case. The types of the values carried by each union case is included in the definition of each case.
The list type is an immutable linked list represented either using a head::tail
notation (::
is the cons operator) or a shorthand as [item1; item2; item3]
. An empty list is written []
. The option type is a discriminated union type with choices Some(x)
or None
. F# types may be generic, implemented as generic .NET types.
F# supports lambda functions and closures.[49] All functions in F# are first class values and are immutable.[49] Functions can be curried. Being first-class values, functions can be passed as arguments to other functions. Like other functional programming languages, F# allows function composition using the >>
and <<
operators.
F# provides sequence expressions[50] that define a sequence seq { ... }
, list [ ... ]
or array [| ... |]
through code that generates values. For example,
seq { for b in 0 .. 25 do
if b < 15 then
yield b*b }
forms a sequence of squares of numbers from 0 to 14 by filtering out numbers from the range of numbers from 0 to 25. Sequences are generators – values are generated on-demand (i.e., are lazily evaluated) – while lists and arrays are evaluated eagerly.
F# uses pattern matching to bind values to names. Pattern matching is also used when accessing discriminated unions – the union is value matched against pattern rules and a rule is selected when a match succeeds. F# also supports active patterns as a form of extensible pattern matching.[51] It is used, for example, when multiple ways of matching on a type exist.[49]
F# supports a general syntax for defining compositional computations called computation expressions. Sequence expressions, asynchronous computations and queries are particular kinds of computation expressions. Computation expressions are an implementation of the monad pattern.[50]
F# support for imperative programming includes
for
loopswhile
loops[| ... |]
syntaxdict [ ... ]
syntax or System.Collections.Generic.Dictionary<_,_>
type.Values and record fields can also be labelled as mutable
. For example:
// Define 'x' with initial value '1'
let mutable x = 1
// Change the value of 'x' to '3'
x <- 3
Also, F# supports access to all CLI types and objects such as those defined in the System.Collections.Generic
namespace defining imperative data structures.
Like other Common Language Infrastructure (CLI) languages, F# can use CLI types through object-oriented programming.[49] F# support for object-oriented programming in expressions includes:
x.Name
{ new obj() with member x.ToString() = "hello"
}new Form()
x :? string
x :?> string
x.Method(someArgument=1)
new Form(Text="Hello")
x.Method(OptionalArgument=1)
Support for object-oriented programming in patterns includes
:? string as s
F# object type definitions can be class, struct, interface, enum, or delegate type definitions, corresponding to the definition forms found in C#. For example, here is a class with a constructor taking a name and age, and declaring two properties.
/// A simple object type definition
type Person(name : string, age : int) =
member x.Name = name
member x.Age = age
F# supports asynchronous programming through asynchronous workflows.[52] An asynchronous workflow is defined as a sequence of commands inside an async{ ... }
, as in
let asynctask =
async { let req = WebRequest.Create(url)
let! response = req.GetResponseAsync()
use stream = response.GetResponseStream()
use streamreader = new System.IO.StreamReader(stream)
return streamreader.ReadToEnd() }
The let!
indicates that the expression on the right (getting the response) should be done asynchronously but the flow should only continue when the result is available. In other words, from the point of view of the code block, it's as if getting the response is a blocking call, whereas from the point of view of the system, the thread won't be blocked and may be used to process other flows until the result needed for this one becomes available.
The async block may be invoked using the Async.RunSynchronously
function. Multiple async blocks can be executed in parallel using the Async.Parallel
function that takes a list of async
objects (in the example, asynctask
is an async object) and creates another async object to run the tasks in the lists in parallel. The resultant object is invoked using Async.RunSynchronously
.[52]
Inversion of control in F# follows this pattern.[52]
Since version 6.0, F# supports creating, consuming and returning .NET tasks directly. [53]
open System.Net.Http
let fetchUrlAsync (url:string) = // string -> Task<string>
task {
use client = new HttpClient()
let! response = client.GetAsync(url)
let! content = response.Content.ReadAsStringAsync()
do! Task.Delay 500
return content
}
// Usage
let fetchPrint() =
let task = task {
let! data = fetchUrlAsync "https://example.com"
printfn $"{data}"
}
task.Wait()
Parallel programming is supported partly through the Async.Parallel
, Async.Start
and other operations that run asynchronous blocks in parallel.
Parallel programming is also supported through the Array.Parallel
functional programming operators in the F# standard library, direct use of the System.Threading.Tasks
task programming model, the direct use of .NET thread pool and .NET threads and through dynamic translation of F# code to alternative parallel execution engines such as GPU[8] code.
The F# type system supports units of measure checking for numbers.[54]
In F#, you can assign units of measure, such as meters or kilograms, to floating point, unsigned integer[55] and signed integer values. This allows the compiler to check that arithmetic involving these values is dimensionally consistent, helping to prevent common programming mistakes by ensuring that, for instance, lengths aren't mistakenly added to times.
The units of measure feature integrates with F# type inference to require minimal type annotations in user code.[56]
[<Measure>] type m // meter
[<Measure>] type s // second
let distance = 100.0<m> // float<m>
let time = 5.0<s> // float<s>
let speed = distance/time // float<m/s>
[<Measure>] type kg // kilogram
[<Measure>] type N = (kg * m)/(s^2) // Newtons
[<Measure>] type Pa = N/(m^2) // Pascals
[<Measure>] type days
let better_age = 3u<days> // uint<days>
The F# static type checker provides this functionality at compile time, but units are erased from the compiled code. Consequently, it is not possible to determine a value's unit at runtime.
F# allows some forms of syntax customizing via metaprogramming to support embedding custom domain-specific languages within the F# language, particularly through computation expressions.[49]
F# includes a feature for run-time meta-programming called quotations.[57] A quotation expression evaluates to an abstract syntax tree representation of the F# expressions. Similarly, definitions labelled with the [<ReflectedDefinition>]
attribute can also be accessed in their quotation form. F# quotations are used for various purposes including to compile F# code into JavaScript[7] and GPU[8] code. Quotations represent their F# code expressions as data for use by other parts of the program while requiring it to be syntactically correct F# code.
F# 3.0 introduced a form of compile-time meta-programming through statically extensible type generation called F# type providers.[58] F# type providers allow the F# compiler and tools to be extended with components that provide type information to the compiler on-demand at compile time. F# type providers have been used to give strongly typed access to connected information sources in a scalable way, including to the Freebase knowledge graph.[59]
In F# 3.0 the F# quotation and computation expression features are combined to implement LINQ queries.[60] For example:
// Use the OData type provider to create types that can be used to access the Northwind database.
open Microsoft.FSharp.Data.TypeProviders
type Northwind = ODataService<"http://services.odata.org/Northwind/Northwind.svc">
let db = Northwind.GetDataContext()
// A query expression.
let query1 = query { for customer in db.Customers do
select customer }
The combination of type providers, queries and strongly typed functional programming is known as information rich programming.[61]
F# supports a variation of the actor programming model through the in-memory implementation of lightweight asynchronous agents. For example, the following code defines an agent and posts 2 messages:
type Message =
| Enqueue of string
| Dequeue of AsyncReplyChannel<Option<string>>
// Provides concurrent access to a list of strings
let listManager = MailboxProcessor.Start(fun inbox ->
let rec messageLoop list = async {
let! msg = inbox.Receive()
match msg with
| Enqueue item ->
return! messageLoop (item :: list)
| Dequeue replyChannel ->
match list with
| [] ->
replyChannel.Reply None
return! messageLoop list
| head :: tail ->
replyChannel.Reply (Some head)
return! messageLoop tail
}
// Start the loop with an empty list
messageLoop []
)
// Usage
async {
// Enqueue some strings
listManager.Post(Enqueue "Hello")
listManager.Post(Enqueue "World")
// Dequeue and process the strings
let! str = listManager.PostAndAsyncReply(Dequeue)
str |> Option.iter (printfn "Dequeued: %s")
}
|> Async.Start
IDE | License | Windows | Linux | macOS | Developer |
---|---|---|---|---|---|
Microsoft Visual Studio | Proprietary (standard) Freeware (community edition) |
Yes | No | Yes | Microsoft |
Visual Studio Code[63] | Proprietary (binary code) MIT License (source code) |
Yes | Yes | Yes | Microsoft |
Rider[64] | Proprietary | Yes | Yes | Yes | JetBrains |
F# is a general-purpose programming language.
The SAFE Stack is an end-to-end F# stack to develop web applications. It uses ASP.NET Core on the server side and Fable on the client side.[65]
An alternative end-to-end F# option is the WebSharper framework.[66]
F# can be used together with the Visual Studio Tools for Xamarin to develop apps for iOS and Android. The Fabulous library provides a more comfortable functional interface.
Among others, F# is used for quantitative finance programming,[67] energy trading and portfolio optimization,[68] machine learning,[69] business intelligence[70] and social gaming on Facebook.[71]
In the 2010s, F# has been positioned as an optimized alternative to C#. F#'s scripting ability and inter-language compatibility with all Microsoft products have made it popular among developers.[72]
F# can be used as a scripting language, mainly for desktop read–eval–print loop (REPL) scripting.[73]
The F# open-source community includes the F# Software Foundation[9] and the F# Open Source Group at GitHub.[10] Popular open-source F# projects include:
F# features a legacy "ML compatibility mode" that can directly compile programs written in a large subset of OCaml roughly, with no functors, objects, polymorphic variants, or other additions.
A few small samples follow:
// This is a comment for a sample hello world program.
printfn "Hello World!"
A record type definition. Records are immutable by default and are compared by structural equality.
type Person = {
FirstName: string
LastName: string
Age: int
}
// Creating an instance of the record
let person = { FirstName = "John"; LastName = "Doe"; Age = 30 }
A Person class with a constructor taking a name and age and two immutable properties.
/// This is a documentation comment for a type definition.
type Person(name : string, age : int) =
member x.Name = name
member x.Age = age
/// class instantiation
let mrSmith = Person("Smith", 42)
A simple example that is often used to demonstrate the syntax of functional languages is the factorial function for non-negative 32-bit integers, here shown in F#:
/// Using pattern matching expression
let rec factorial n =
match n with
| 0 -> 1
| _ -> n * factorial (n - 1)
/// For a single-argument functions there is syntactic sugar (pattern matching function):
let rec factorial = function
| 0 -> 1
| n -> n * factorial (n - 1)
/// Using fold and range operator
let factorial n = [1..n] |> Seq.fold (*) 1
Iteration examples:
/// Iteration using a 'for' loop
let printList lst =
for x in lst do
printfn $"{x}"
/// Iteration using a higher-order function
let printList2 lst =
List.iter (printfn "%d") lst
/// Iteration using a recursive function and pattern matching
let rec printList3 lst =
match lst with
| [] -> ()
| h :: t ->
printfn "%d" h
printList3 t
Fibonacci examples:
/// Fibonacci Number formula
[<TailCall>]
let fib n =
let rec g n f0 f1 =
match n with
| 0 -> f0
| 1 -> f1
| _ -> g (n - 1) f1 (f0 + f1)
g n 0 1
/// Another approach - a lazy infinite sequence of Fibonacci numbers
let fibSeq = Seq.unfold (fun (a,b) -> Some(a+b, (b, a+b))) (0,1)
// Print even fibs
[1 .. 10]
|> List.map fib
|> List.filter (fun n -> (n % 2) = 0)
|> printList
// Same thing, using a list expression
[ for i in 1..10 do
let r = fib i
if r % 2 = 0 then yield r ]
|> printList
A sample Windows Forms program:
// Open the Windows Forms library
open System.Windows.Forms
// Create a window and set a few properties
let form = new Form(Visible=true, TopMost=true, Text="Welcome to F#")
// Create a label to show some text in the form
let label =
let x = 3 + (4 * 5)
new Label(Text = $"{x}")
// Add the label to the form
form.Controls.Add(label)
// Finally, run the form
[<System.STAThread>]
Application.Run(form)
Asynchronous parallel programming sample (parallel CPU and I/O tasks):
/// A simple prime number detector
let isPrime (n:int) =
let bound = int (sqrt (float n))
seq {2 .. bound} |> Seq.forall (fun x -> n % x <> 0)
// We are using async workflows
let primeAsync n =
async { return (n, isPrime n) }
/// Return primes between m and n using multiple threads
let primes m n =
seq {m .. n}
|> Seq.map primeAsync
|> Async.Parallel
|> Async.RunSynchronously
|> Array.filter snd
|> Array.map fst
// Run a test
primes 1000000 1002000
|> Array.iter (printfn "%d")
Seamless Wikipedia browsing. On steroids.
Every time you click a link to Wikipedia, Wiktionary or Wikiquote in your browser's search results, it will show the modern Wikiwand interface.
Wikiwand extension is a five stars, simple, with minimum permission required to keep your browsing private, safe and transparent.